home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / byt85may.lbr / PI2.ASC < prev    next >
Text File  |  1985-09-15  |  1KB  |  40 lines
  1. 100 REM            pi2.bas
  2. 105 REM
  3. 110 REM       copyrighted 1984
  4. 115 REM              by
  5. 120 REM       David J. Crawford
  6. 125 REM
  7. 130 REM   For private, non-commercial
  8. 135 REM            use only
  9. 140 REM
  10. 150 REM
  11. 160 REM    This program computes PI using the Taylor's Series Expansion
  12. 170 REM  of "16 ARCTAN 1/5 - 4 ARCTAN 1/239."
  13. 180 REM
  14. 190 DEFDBL B-G,P
  15. 200 A=12 : B=16 : C=5
  16. 210 GOSUB 280
  17. 220 P1=P
  18. 230 A=4 : B=4 : C=239
  19. 240 GOSUB 280
  20. 250 PRINT "16 ARCTAN 1/5         -        4 ARCTAN 1/239       =      PI"
  21. 260 PRINT P1,P,P1-P
  22. 270 STOP
  23. 280 REM  ***  This subroutine sums "A" terms of the Taylor's Series
  24. 290 REM       for "B" times the angle whose tangent is (1/"C")
  25. 300 REM       and returns the sum as "P."
  26. 310 PRINT "TAYLOR'S SERIES FOR";B;"ARCTAN( 1 /";C;")"
  27. 320 PRINT "TERM #";TAB(10);"RATIO";TAB(38);"DECIMAL";TAB(61);"SUBTOTAL"
  28. 330 D=1 : E=1 : F=C : P=0
  29. 340 FOR X=1 TO A
  30. 350 G=E*F
  31. 360 P=P+D*B/G
  32. 370 PRINT X;TAB(8)
  33. 380 IF SGN(D)=1 THEN PRINT "+"; ELSE PRINT "-";
  34. 390 PRINT STR$(B);" /";STR$(G);TAB(37);D*B/G;TAB(60);P
  35. 400 F=F*C*C
  36. 410 E=E+2
  37. 420 D=-D
  38. 430 NEXT X
  39. 440 PRINT : RETURN
  40.